import space.kscience.gradle.DependencyConfiguration
import space.kscience.gradle.FXModule

plugins {
    id("space.kscience.gradle.mpp")
    application
}

kscience {
    val fxVersion: String by rootProject.extra
    useFx(FXModule.CONTROLS, version = fxVersion, configuration = DependencyConfiguration.IMPLEMENTATION)
    application()
}

kotlin {
    jvm {
        withJava()
    }

    js {
        useCommonJs()
        browser {
            commonWebpackConfig {
                cssSupport{
                    enabled.set(false)
                }
            }
        }
    }

    sourceSets {
        commonMain {
            dependencies {
                implementation(project(":visionforge-solid"))
                implementation(project(":visionforge-gdml"))
            }
        }
        jvmMain {
            dependencies {
                implementation(project(":visionforge-fx"))
                implementation("ch.qos.logback:logback-classic:1.2.11")
            }
        }
        jsMain {
            dependencies {
                implementation(project(":ui:ring"))
                implementation(project(":visionforge-threejs"))
                implementation(npm("react-file-drop", "3.0.6"))
            }
        }
    }
}

application {
    mainClass.set("space.kscience.visionforge.gdml.demo.GdmlFxDemoAppKt")
}

val convertGdmlToJson by tasks.creating(JavaExec::class) {
    group = "application"
    classpath = sourceSets["main"].runtimeClasspath
    mainClass.set("space.kscience.dataforge.vis.spatial.gdml.demo.SaveToJsonKt")
}