benchmarks/build.gradle

@@ -21,7 +21,7 @@ dependencies {
     //jmh project(':kmath-core')
 }
 
-jmh{
+jmh {
     warmupIterations = 1
 }
 

build.gradle.kts

@@ -1,60 +1,25 @@
-import com.moowork.gradle.node.NodeExtension
-import com.moowork.gradle.node.npm.NpmTask
-import com.moowork.gradle.node.task.NodeTask
-import org.jetbrains.kotlin.gradle.dsl.KotlinMultiplatformExtension
-import org.jetbrains.kotlin.gradle.tasks.Kotlin2JsCompile
-import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
-
-buildscript {
-    val kotlinVersion: String by rootProject.extra("1.3.30")
-    val ioVersion: String by rootProject.extra("0.1.5")
-    val coroutinesVersion: String by rootProject.extra("1.2.0")
-    val atomicfuVersion: String by rootProject.extra("0.12.1")
-    val dokkaVersion: String by rootProject.extra("0.9.17")
-    val serializationVersion: String by rootProject.extra("0.10.0")
-
-    repositories {
-        jcenter()
-        maven("https://dl.bintray.com/kotlin/kotlin-eap")
-    }
-
-    dependencies {
-        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion")
-        classpath("org.jfrog.buildinfo:build-info-extractor-gradle:4+")
-        classpath("com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4")
-        classpath("org.jetbrains.dokka:dokka-gradle-plugin:$dokkaVersion")
-        //classpath("org.jetbrains.kotlin:kotlin-frontend-plugin:0.0.45")
-        //classpath("org.openjfx:javafx-plugin:0.0.7")
-    }
-}
-
-plugins {
-    id("com.jfrog.artifactory") version "4.9.1" apply false
-    id("com.moowork.node") version "1.3.1" apply false
-}
-
 val kmathVersion by extra("0.1.2-dev-1")
 
 allprojects {
-    apply(plugin = "maven")
-    apply(plugin = "maven-publish")
-    apply(plugin = "com.jfrog.artifactory")
+//    apply(plugin = "maven")
+//    apply(plugin = "maven-publish")
+//    apply(plugin = "com.jfrog.artifactory")
 
     repositories {
         jcenter()
         maven("https://kotlin.bintray.com/kotlinx")
     }
+    
     group = "scientifik"
     version = kmathVersion
 }
 
 subprojects {
-    if(name.startsWith("kmath")) {
-        // apply bintray configuration
-        apply(from = "${rootProject.rootDir}/gradle/bintray.gradle")
-
-        //apply artifactory configuration
-        apply(from = "${rootProject.rootDir}/gradle/artifactory.gradle")
+    // Actually, probably we should apply it to plugins explicitly
+    // We also can merge them to single kmath-publish plugin
+    if (name.startsWith("kmath")) {
+        apply(plugin = "bintray-config")
+        apply(plugin = "artifactory-config")
     }
     //    dokka {
 //        outputFormat = "html"
@@ -65,161 +30,4 @@ subprojects {
 //           from javadoc . destinationDir
 //            classifier = "javadoc"
 //    }
-
-    // Create empty jar for sources classifier to satisfy maven requirements
-    val stubSources by tasks.registering(Jar::class) {
-        archiveClassifier.set("sources")
-        //from(sourceSets.main.get().allSource)
-    }
-
-    // Create empty jar for javadoc classifier to satisfy maven requirements
-    val stubJavadoc by tasks.registering(Jar::class) {
-        archiveClassifier.set("javadoc")
-    }
-
-    tasks.withType<KotlinCompile> {
-        kotlinOptions {
-            jvmTarget = "1.8"
-        }
-    }
-
-
-    afterEvaluate {
-        extensions.findByType<KotlinMultiplatformExtension>()?.apply {
-            jvm {
-                compilations.all {
-                    kotlinOptions {
-                        jvmTarget = "1.8"
-                        //freeCompilerArgs = listOf("-Xno-call-assertions", "-Xno-param-assertions")
-                    }
-                }
-            }
-
-            js {
-                compilations.all {
-                    tasks.getByName(compileKotlinTaskName) {
-                        kotlinOptions {
-                            metaInfo = true
-                            sourceMap = true
-                            sourceMapEmbedSources = "always"
-                            moduleKind = "commonjs"
-                        }
-                    }
-                }
-
-                configure(listOf(compilations["main"])) {
-                    tasks.getByName(compileKotlinTaskName) {
-                        kotlinOptions {
-                            main = "call"
-                        }
-                    }
-                }
-
-
-                val runJsTests by ext(false)
-
-                if(runJsTests) {
-                    apply(plugin = "com.moowork.node")
-                    configure<NodeExtension> {
-                        nodeModulesDir = file("$buildDir/node_modules")
-                    }
-
-                    val compileKotlinJs by tasks.getting(Kotlin2JsCompile::class)
-                    val compileTestKotlinJs by tasks.getting(Kotlin2JsCompile::class)
-
-                    val populateNodeModules by tasks.registering(Copy::class) {
-                        dependsOn(compileKotlinJs)
-                        from(compileKotlinJs.destinationDir)
-
-                        compilations["test"].runtimeDependencyFiles.forEach {
-                            if (it.exists() && !it.isDirectory) {
-                                from(zipTree(it.absolutePath).matching { include("*.js") })
-                            }
-                        }
-
-                        into("$buildDir/node_modules")
-                    }
-
-                    val installMocha by tasks.registering(NpmTask::class) {
-                        setWorkingDir(buildDir)
-                        setArgs(listOf("install", "mocha"))
-                    }
-
-                    val runMocha by tasks.registering(NodeTask::class) {
-                        dependsOn(compileTestKotlinJs, populateNodeModules, installMocha)
-                        setScript(file("$buildDir/node_modules/mocha/bin/mocha"))
-                        setArgs(listOf(compileTestKotlinJs.outputFile))
-                    }
-
-                    tasks["jsTest"].dependsOn(runMocha)
-                }
-            }
-
-            sourceSets {
-
-                val commonMain by getting {
-                    dependencies {
-                        api(kotlin("stdlib"))
-                    }
-                }
-                val commonTest by getting {
-                    dependencies {
-                        implementation(kotlin("test-common"))
-                        implementation(kotlin("test-annotations-common"))
-                    }
-                }
-                val jvmMain by getting {
-                    dependencies {
-                        api(kotlin("stdlib-jdk8"))
-                    }
-                }
-                val jvmTest by getting {
-                    dependencies {
-                        implementation(kotlin("test"))
-                        implementation(kotlin("test-junit"))
-                    }
-                }
-                val jsMain by getting {
-                    dependencies {
-                        api(kotlin("stdlib-js"))
-                    }
-                }
-                val jsTest by getting {
-                    dependencies {
-                        implementation(kotlin("test-js"))
-                    }
-                }
-            }
-
-            targets.all {
-                sourceSets.all {
-                    languageSettings.progressiveMode = true
-                    languageSettings.enableLanguageFeature("InlineClasses")
-                    languageSettings.useExperimentalAnnotation("ExperimentalContracts")
-                    //languageSettings.enableLanguageFeature("Contracts")
-                }
-            }
-
-            configure<PublishingExtension> {
-
-                publications.filterIsInstance<MavenPublication>().forEach { publication ->
-                    if (publication.name == "kotlinMultiplatform") {
-                        // for our root metadata publication, set artifactId with a package and project name
-                        publication.artifactId = project.name
-                    } else {
-                        // for targets, set artifactId with a package, project name and target name (e.g. iosX64)
-                        publication.artifactId = "${project.name}-${publication.name}"
-                    }
-                }
-
-                targets.all {
-                    val publication = publications.findByName(name) as MavenPublication
-
-                    // Patch publications with fake javadoc
-                    publication.artifact(stubJavadoc.get())
-                }
-            }
-        }
-    }
-
 }

buildSrc/build.gradle.kts

@@ -0,0 +1,18 @@
+plugins {
+    `kotlin-dsl`
+}
+
+repositories {
+    gradlePluginPortal()
+    jcenter()
+}
+
+val kotlinVersion = "1.3.30"
+
+// Add plugins used in buildSrc as dependencies, also we should specify version only here
+dependencies {
+    implementation("org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion")
+    implementation("org.jfrog.buildinfo:build-info-extractor-gradle:4.9.5")
+    implementation("com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4")
+    implementation("com.moowork.gradle:gradle-node-plugin:1.3.1")
+}

buildSrc/src/main/kotlin/Versions.kt

@@ -0,0 +1,10 @@
+// Instead of defining runtime properties and use them dynamically
+// define version in buildSrc and have autocompletion and compile-time check
+// Also dependencies itself can be moved here
+object Versions {
+    val ioVersion = "0.1.8"
+    val coroutinesVersion = "1.2.0"
+    val atomicfuVersion = "0.12.6"
+    // This version is not used and IDEA shows this property as unused
+    val dokkaVersion = "0.9.18"
+}

buildSrc/src/main/kotlin/artifactory-config.gradle.kts

@@ -0,0 +1,38 @@
+import groovy.lang.GroovyObject
+import org.jfrog.gradle.plugin.artifactory.dsl.PublisherConfig
+import org.jfrog.gradle.plugin.artifactory.dsl.ResolverConfig
+
+plugins {
+    id("com.jfrog.artifactory") version "4.9.5"
+}
+
+artifactory {
+    val artifactoryUser: String? by project
+    val artifactoryPassword: String? by project
+    val artifactoryContextUrl = "http://npm.mipt.ru:8081/artifactory"
+
+    setContextUrl(artifactoryContextUrl)//The base Artifactory URL if not overridden by the publisher/resolver
+    publish(delegateClosureOf<PublisherConfig> {
+        repository(delegateClosureOf<GroovyObject> {
+            setProperty("repoKey", "gradle-dev-local")
+            setProperty("username", artifactoryUser)
+            setProperty("password", artifactoryPassword)
+        })
+
+        defaults(delegateClosureOf<GroovyObject>{
+            invokeMethod("publications", arrayOf("jvm", "js", "kotlinMultiplatform", "metadata"))
+            //TODO: This property is not available for ArtifactoryTask
+            //setProperty("publishBuildInfo", false)
+            setProperty("publishArtifacts", true)
+            setProperty("publishPom", true)
+            setProperty("publishIvy", false)
+        })
+    })
+    resolve(delegateClosureOf<ResolverConfig> {
+        repository(delegateClosureOf<GroovyObject> {
+            setProperty("repoKey", "gradle-dev")
+            setProperty("username", artifactoryUser)
+            setProperty("password", artifactoryPassword)
+        })
+    })
+}

buildSrc/src/main/kotlin/bintray-config.gradle.kts

@@ -0,0 +1,97 @@
+@file:Suppress("UnstableApiUsage")
+
+import com.jfrog.bintray.gradle.BintrayExtension.PackageConfig
+import com.jfrog.bintray.gradle.BintrayExtension.VersionConfig
+
+// Old bintray.gradle script converted to real Gradle plugin (precompiled script plugin)
+// It now has own dependencies and support type safe accessors
+// Syntax is pretty close to what we had in Groovy
+// (excluding Property.set and bintray dynamic configs)
+
+plugins {
+    id("com.jfrog.bintray") version "1.8.4"
+    `maven-publish`
+}
+
+val vcs = "https://github.com/mipt-npm/kmath"
+
+// Configure publishing
+publishing {
+    repositories {
+        maven("https://bintray.com/mipt-npm/scientifik")
+    }
+
+    // Process each publication we have in this project
+    publications.filterIsInstance<MavenPublication>().forEach { publication ->
+
+        // use type safe pom config GSL insterad of old dynamic
+        publication.pom {
+            name.set(project.name)
+            description.set(project.description)
+            url.set(vcs)
+
+            licenses {
+                license {
+                    name.set("The Apache Software License, Version 2.0")
+                    url.set("http://www.apache.org/licenses/LICENSE-2.0.txt")
+                    distribution.set("repo")
+                }
+            }
+            developers {
+                developer {
+                    id.set("MIPT-NPM")
+                    name.set("MIPT nuclear physics methods laboratory")
+                    organization.set("MIPT")
+                    organizationUrl.set("http://npm.mipt.ru")
+                }
+
+            }
+            scm {
+                url.set(vcs)
+            }
+        }
+
+    }
+}
+
+bintray {
+    // delegates for runtime properties
+    val bintrayUser: String? by project
+    val bintrayApiKey: String? by project
+    user = bintrayUser ?: System.getenv("BINTRAY_USER")
+    key = bintrayApiKey ?: System.getenv("BINTRAY_API_KEY")
+    publish = true
+    override = true // for multi-platform Kotlin/Native publishing
+
+    // We have to use delegateClosureOf because bintray supports only dynamic groovy syntax
+    // this is a problem of this plugin
+    pkg(delegateClosureOf<PackageConfig> {
+        userOrg = "mipt-npm"
+        repo = "scientifik"
+        name = "scientifik.kmath"
+        issueTrackerUrl = "https://github.com/mipt-npm/kmath/issues"
+        setLicenses("Apache-2.0")
+        vcsUrl = vcs
+        version(delegateClosureOf<VersionConfig> {
+            name = project.version.toString()
+            vcsTag = project.version.toString()
+            released = java.util.Date().toString()
+        })
+    })
+
+    tasks {
+        bintrayUpload {
+            dependsOn(publishToMavenLocal)
+            doFirst {
+                setPublications(project.publishing.publications
+                    .filterIsInstance<MavenPublication>()
+                    .filter { !it.name.contains("-test") && it.name != "kotlinMultiplatform" }
+                    .map {
+                        println("""Uploading artifact "${it.groupId}:${it.artifactId}:${it.version}" from publication "${it.name}""")
+                        it.name //https://github.com/bintray/gradle-bintray-plugin/issues/256
+                    })
+            }
+        }
+
+    }
+}

buildSrc/src/main/kotlin/js-test.gradle.kts

@@ -0,0 +1,44 @@
+import com.moowork.gradle.node.npm.NpmTask
+import com.moowork.gradle.node.task.NodeTask
+import org.gradle.kotlin.dsl.*
+import org.jetbrains.kotlin.gradle.tasks.Kotlin2JsCompile
+
+plugins {
+    id("com.moowork.node")
+    kotlin("multiplatform")
+}
+
+node {
+    nodeModulesDir = file("$buildDir/node_modules")
+}
+
+val compileKotlinJs by tasks.getting(Kotlin2JsCompile::class)
+val compileTestKotlinJs by tasks.getting(Kotlin2JsCompile::class)
+
+val populateNodeModules by tasks.registering(Copy::class) {
+    dependsOn(compileKotlinJs)
+    from(compileKotlinJs.destinationDir)
+
+    kotlin.js().compilations["test"].runtimeDependencyFiles.forEach {
+        if (it.exists() && !it.isDirectory) {
+            from(zipTree(it.absolutePath).matching { include("*.js") })
+        }
+    }
+
+    into("$buildDir/node_modules")
+}
+
+val installMocha by tasks.registering(NpmTask::class) {
+    setWorkingDir(buildDir)
+    setArgs(listOf("install", "mocha"))
+}
+
+val runMocha by tasks.registering(NodeTask::class) {
+    dependsOn(compileTestKotlinJs, populateNodeModules, installMocha)
+    setScript(file("$buildDir/node_modules/mocha/bin/mocha"))
+    setArgs(listOf(compileTestKotlinJs.outputFile))
+}
+
+tasks["jsTest"].dependsOn(runMocha)
+
+

buildSrc/src/main/kotlin/multiplatform-config.gradle.kts

@@ -0,0 +1,118 @@
+import org.gradle.kotlin.dsl.*
+
+plugins {
+    kotlin("multiplatform")
+    `maven-publish`
+}
+
+
+kotlin {
+    jvm {
+        compilations.all {
+            kotlinOptions {
+                jvmTarget = "1.8"
+                // This was used in kmath-koma, but probably if we need it better to apply it for all modules
+                freeCompilerArgs = listOf("-progressive")
+            }
+        }
+    }
+
+    js {
+        compilations.all {
+            kotlinOptions {
+                metaInfo = true
+                sourceMap = true
+                sourceMapEmbedSources = "always"
+                moduleKind = "commonjs"
+            }
+        }
+
+        compilations.named("main") {
+            kotlinOptions {
+                main = "call"
+            }
+        }
+    }
+
+    sourceSets.invoke {
+        commonMain {
+            dependencies {
+                api(kotlin("stdlib"))
+            }
+        }
+        commonTest {
+            dependencies {
+                implementation(kotlin("test-common"))
+                implementation(kotlin("test-annotations-common"))
+            }
+        }
+        "jvmMain" {
+            dependencies {
+                api(kotlin("stdlib-jdk8"))
+            }
+        }
+        "jvmTest" {
+            dependencies {
+                implementation(kotlin("test"))
+                implementation(kotlin("test-junit"))
+            }
+        }
+        "jsMain" {
+            dependencies {
+                api(kotlin("stdlib-js"))
+            }
+        }
+        "jsTest" {
+            dependencies {
+                implementation(kotlin("test-js"))
+            }
+        }
+    }
+
+    targets.all {
+        sourceSets.all {
+            languageSettings.progressiveMode = true
+            languageSettings.enableLanguageFeature("InlineClasses")
+        }
+    }
+
+    // Create empty jar for sources classifier to satisfy maven requirements
+    val stubSources by tasks.registering(Jar::class){
+        archiveClassifier.set("sources")
+        //from(sourceSets.main.get().allSource)
+    }
+
+    // Create empty jar for javadoc classifier to satisfy maven requirements
+    val stubJavadoc by tasks.registering(Jar::class) {
+        archiveClassifier.set("javadoc")
+    }
+
+
+    publishing {
+
+        publications.filterIsInstance<MavenPublication>().forEach { publication ->
+            if (publication.name == "kotlinMultiplatform") {
+                // for our root metadata publication, set artifactId with a package and project name
+                publication.artifactId = project.name
+            } else {
+                // for targets, set artifactId with a package, project name and target name (e.g. iosX64)
+                publication.artifactId = "${project.name}-${publication.name}"
+            }
+        }
+
+        targets.all {
+            val publication = publications.findByName(name) as MavenPublication
+
+            // Patch publications with fake javadoc
+            publication.artifact(stubJavadoc.get())
+        }
+    }
+
+    // Apply JS test configuration
+    val runJsTests by ext(false)
+
+    if (runJsTests) {
+        apply(plugin = "js-test")
+    }
+
+}

kmath-core/build.gradle.kts

@@ -1,23 +1,13 @@
 plugins {
-    kotlin("multiplatform")
+    `multiplatform-config`
 }
 
-val ioVersion: String by rootProject.extra
-
-
-kotlin {
-    jvm()
-    js()
-
-    sourceSets {
-        val commonMain by getting {
+kotlin.sourceSets {
+    commonMain {
         dependencies {
             api(project(":kmath-memory"))
         }
     }
-//        mingwMain {
-//        }
-//        mingwTest {
-//        }
-    }
+    //mingwMain {}
+    //mingwTest {}
 }

kmath-coroutines/build.gradle.kts

@@ -1,46 +1,26 @@
 plugins {
-    kotlin("multiplatform")
+    `multiplatform-config`
+    id("kotlinx-atomicfu") version Versions.atomicfuVersion
 }
 
-val coroutinesVersion: String by rootProject.extra
-
-kotlin {
-    jvm()
-    js()
-
-    sourceSets {
-        val commonMain by getting {
+kotlin.sourceSets {
+    commonMain {
         dependencies {
             api(project(":kmath-core"))
-                api("org.jetbrains.kotlinx:kotlinx-coroutines-core-common:$coroutinesVersion")
+            api("org.jetbrains.kotlinx:kotlinx-coroutines-core-common:${Versions.coroutinesVersion}")
+            compileOnly("org.jetbrains.kotlinx:atomicfu-common:${Versions.atomicfuVersion}")
         }
     }
-        val commonTest by getting {
+    jvmMain {
         dependencies {
-                implementation(kotlin("test-common"))
-                implementation(kotlin("test-annotations-common"))
+            api("org.jetbrains.kotlinx:kotlinx-coroutines-core:${Versions.coroutinesVersion}")
+            compileOnly("org.jetbrains.kotlinx:atomicfu:${Versions.atomicfuVersion}")
         }
     }
-        val jvmMain by getting {
+    jsMain {
         dependencies {
-                api("org.jetbrains.kotlinx:kotlinx-coroutines-core:$coroutinesVersion")
-            }
-        }
-        val jvmTest by getting {
-            dependencies {
-                implementation(kotlin("test"))
-                implementation(kotlin("test-junit"))
-            }
-        }
-        val jsMain by getting {
-            dependencies {
-                api("org.jetbrains.kotlinx:kotlinx-coroutines-core-js:$coroutinesVersion")
-            }
-        }
-        val jsTest by getting {
-            dependencies {
-                implementation(kotlin("test-js"))
-            }
+            api("org.jetbrains.kotlinx:kotlinx-coroutines-core-js:${Versions.coroutinesVersion}")
+            compileOnly("org.jetbrains.kotlinx:atomicfu-js:${Versions.atomicfuVersion}")
         }
     }
 }

kmath-histograms/build.gradle.kts

@@ -1,34 +1,10 @@
 plugins {
-    kotlin("multiplatform")
+    `multiplatform-config`
 }
 
-kotlin {
-    jvm()
-    js()
-
-    sourceSets {
-
-        val commonMain by getting {
+// Just an example how we can collapse nested DSL for simple declarations
+kotlin.sourceSets.commonMain {
     dependencies {
         api(project(":kmath-core"))
     }
-        }
-        val commonTest by getting {
-            dependencies {
-                implementation(kotlin("test-common"))
-                implementation(kotlin("test-annotations-common"))
-            }
-        }
-        val jvmTest by getting {
-            dependencies {
-                implementation(kotlin("test"))
-                implementation(kotlin("test-junit"))
-            }
-        }
-        val jsTest by getting {
-            dependencies {
-                implementation(kotlin("test-js"))
-            }
-        }
-    }
 }

kmath-koma/build.gradle.kts

@@ -1,57 +1,31 @@
 plugins {
-    kotlin("multiplatform")
+    `multiplatform-config`
 }
 
 repositories {
     maven("http://dl.bintray.com/kyonifer/maven")
 }
 
-kotlin {
-    jvm {
-        compilations.all {
-            kotlinOptions {
-                jvmTarget = "1.8"
-                freeCompilerArgs += "-progressive"
-            }
-        }
-    }
-    js()
-
-    sourceSets {
-
-        val commonMain by getting {
+kotlin.sourceSets {
+    commonMain {
         dependencies {
             api(project(":kmath-core"))
             api("com.kyonifer:koma-core-api-common:0.12")
         }
     }
-        val commonTest by getting {
-            dependencies {
-                implementation(kotlin("test-common"))
-                implementation(kotlin("test-annotations-common"))
-            }
-        }
-        val jvmMain by getting {
+    jvmMain {
         dependencies {
             api("com.kyonifer:koma-core-api-jvm:0.12")
         }
     }
-        val jvmTest by getting {
+    jvmTest {
         dependencies {
-                implementation(kotlin("test"))
-                implementation(kotlin("test-junit"))
             implementation("com.kyonifer:koma-core-ejml:0.12")
         }
     }
-        val jsMain by getting {
+    jsMain {
         dependencies {
             api("com.kyonifer:koma-core-api-js:0.12")
         }
     }
-        val jsTest by getting {
-            dependencies {
-                implementation(kotlin("test-js"))
-            }
-        }
-    }
 }

kmath-memory/build.gradle.kts

@@ -1,16 +1,3 @@
 plugins {
-    kotlin("multiplatform")
-}
-
-val ioVersion: String by rootProject.extra
-
-
-kotlin {
-    jvm()
-    js()
-//        mingwMain {
-//        }
-//        mingwTest {
-//        }
-    
+    `multiplatform-config`
 }

kmath-prob/build.gradle.kts

@@ -0,0 +1,29 @@
+plugins {
+    `multiplatform-config`
+    id("kotlinx-atomicfu") version Versions.atomicfuVersion
+}
+
+kotlin.sourceSets {
+    commonMain {
+        dependencies {
+            api(project(":kmath-core"))
+            api(project(":kmath-coroutines"))
+            compileOnly("org.jetbrains.kotlinx:atomicfu-common:${Versions.atomicfuVersion}")
+        }
+    }
+    jvmMain {
+        dependencies {
+            compileOnly("org.jetbrains.kotlinx:atomicfu:${Versions.atomicfuVersion}")
+        }
+    }
+    jsMain {
+        dependencies {
+            compileOnly("org.jetbrains.kotlinx:atomicfu-js:${Versions.atomicfuVersion}")
+        }
+    }
+
+}
+
+atomicfu {
+    variant = "VH"
+}

kmath-streaming/build.gradle.kts

@@ -1,9 +1,9 @@
 plugins {
-    kotlin("multiplatform")
-    id("kotlinx-atomicfu") version "0.12.4"
+    `multiplatform-config`
+    id("kotlinx-atomicfu") version Versions.atomicfuVersion
 }
 
-val atomicfuVersion: String by rootProject.extra
+
 
 kotlin {
     jvm ()
@@ -14,17 +14,17 @@ kotlin {
             dependencies {
                 api(project(":kmath-core"))
                 api(project(":kmath-coroutines"))
-                compileOnly("org.jetbrains.kotlinx:atomicfu-common:$atomicfuVersion")
+                compileOnly("org.jetbrains.kotlinx:atomicfu-common:${Versions.atomicfuVersion}")
             }
         }
         val jvmMain by getting {
             dependencies {
-                compileOnly("org.jetbrains.kotlinx:atomicfu:$atomicfuVersion")
+                compileOnly("org.jetbrains.kotlinx:atomicfu:${Versions.atomicfuVersion}")
             }
         }
         val jsMain by getting {
             dependencies {
-                compileOnly("org.jetbrains.kotlinx:atomicfu-js:$atomicfuVersion")
+                compileOnly("org.jetbrains.kotlinx:atomicfu-js:${Versions.atomicfuVersion}")
             }
         }
 

kmath-streaming/src/jvmTest/kotlin/scientifik/kmath/streaming/RingBufferTest.kt

@@ -1,8 +1,8 @@
 package scientifik.kmath.streaming
 
 import kotlinx.coroutines.runBlocking
+import org.junit.Test
 import scientifik.kmath.structures.asSequence
-import kotlin.test.Test
 import kotlin.test.assertEquals
 
 class RingBufferTest {

settings.gradle.kts

@@ -10,9 +10,6 @@ pluginManagement {
                 "kotlinx-atomicfu" -> {
                     useModule("org.jetbrains.kotlinx:atomicfu-gradle-plugin:${requested.version}")
                 }
-                "kotlin-multiplatform" ->{
-                    useModule("org.jetbrains.kotlin:kotlin-gradle-plugin:${requested.version}")
-                }
             }
         }
     }
@@ -30,5 +27,6 @@ include(
     ":kmath-commons",
     ":kmath-koma",
     ":kmath-streaming",
+    ":kmath-prob",
     ":benchmarks"
 )