apply plugin: 'application'

if (!hasProperty('mainClass')) {
    ext.mainClass = 'inr.numass.Main'
}
mainClassName = mainClass

description = """The main head of all numass projects"""

ext{
    defaultNumassPath = 'D:\\loss-2011\\'
}

dependencies {
    compile group: 'commons-cli', name: 'commons-cli', version:'1.+'
    compile group: 'commons-io', name: 'commons-io', version:'2.+'
    compile project(':dataforge-fitting:dataforge-minuit')
    compile project(':dataforge-fx')
    compile project(':dataforge-grind')
    compile project(':dataforge-plots')
}

task runNumass(dependsOn: classes, type : JavaExec){
    main mainClass
    classpath = sourceSets.main.runtimeClasspath
    workingDir defaultNumassPath
    description "run Main method in the current numass working directory"
    group "numass"
}

task debugNumass(dependsOn: classes, type: JavaExec) {
    main mainClass
    classpath = sourceSets.main.runtimeClasspath
    workingDir defaultNumassPath
    ignoreExitValue = true
    debug = true
    description "debug Main method in the current numass working directory"
    group "numass"    
}

task listActions(dependsOn: classes, type: JavaExec) {
    main mainClass
    args "-lc"
    classpath = sourceSets.main.runtimeClasspath
    description "print a list of available actions as via -lc command line parameter"
    group "numass"    
}